Re: [PATCH v3 2/4] x86/cpufeatures: Generate a feature mask header based on build config

[Xin Li]

On 6/26/2024 4:36 AM, Nikolay Borisov wrote:
> On 22.06.24 г. 20:14 ч., Xin Li (Intel) wrote:
> > From: "H. Peter Anvin (Intel)" <hpa@xxxxxxxxx>
> >
> > Introduce an AWK script to auto-generate a header with required and
> > disabled feature masks based on <asm/cpufeatures.h> and current build
> > config. Thus for any CPU feature with a build config, e.g., X86_FRED,
> > simply add
> >
> > config X86_DISABLED_FEATURE_FRED
> >     def_bool y
> >     depends on !X86_FRED
> >
> > to arch/x86/Kconfig.cpufeatures, instead of adding a conditional CPU
> > feature disable flag, e.g., DISABLE_FRED.
> >
> > Lastly the generated required and disabled feature masks will be added
> > to their corresponding feature masks for this particular compile-time
> > configuration.
> >
> > [ Xin: build integration improvements ]
> >
> > Signed-off-by: H. Peter Anvin (Intel) <hpa@xxxxxxxxx>
> > Signed-off-by: Xin Li (Intel) <xin@xxxxxxxxx>
>
> Overall LGTM, some minor points below.
>
>
> Reviewed-by: Nikolay Borisov <nik.borisov@xxxxxxxx>

Thanks!

> <snip>
>
> > diff --git a/arch/x86/tools/featuremasks.awk 
> > b/arch/x86/tools/featuremasks.awk
> > new file mode 100755
> > index 000000000000..989b021e73d3
> > --- /dev/null
> > +++ b/arch/x86/tools/featuremasks.awk
> > @@ -0,0 +1,84 @@
> > +#!/usr/bin/awk
> > +#
> > +# Convert cpufeatures.h to a list of compile-time masks
> > +# Note: this blithly assumes that each word has at least one
> > +# feature defined in it; if not, something else is wrong!
> > +#
> > +
> > +BEGIN {
> > +    printf "#ifndef _ASM_X86_FEATUREMASKS_H\n";
> > +    printf "#define _ASM_X86_FEATUREMASKS_H\n\n";
> > +
> > +    file = 0
> > +}
> > +
> > +BEGINFILE {
> > +    switch (++file) {
> > +    case 1:            # cpufeatures.h
> > +        FPAT = "#[ \t]*[a-z]+|[A-Za-z0-9_]+|[^ \t]";
> > +        break;
> > +    case 2:            # .config
> > +        FPAT = "CONFIG_[A-Z0-9_]+|is not set|[yn]";
> > +        break;
> > +    }
> > +}
> > +
>
> IMO this script could use a bit of high-level comments. Something like:
>
>
> # Create a dictionary of sorts, containing all defined feature bits
> > +file == 1 && $1 ~ /^#[ \t]*define$/ && $2 ~ /^X86_FEATURE_/ &&
> > +$3 == "(" && $5 == "*" && $7 == "+" && $9 == ")" {
> > +    nfeat = $4 * $6 + $8;
> > +    feat = $2;
> > +    sub(/^X86_FEATURE_/, "", feat);
> > +    feats[nfeat] = feat;
> > +}
>
> > +file == 1 && $1 ~ /^#[ \t]*define$/ && $2 == "NCAPINTS" {
> > +    ncapints = strtonum($3);
> > +}
> > +
>
> # Create a dictionary featstat[REQUIRED|DISABLED, FEATURE_NAME] = on | off
>
> > +file == 2 && $1 ~ /^CONFIG_X86_[A-Z]*_FEATURE_/ {
> > +    on = ($2 == "y");
> > +    if (split($1, fs, "CONFIG_X86_|_FEATURE_") == 3)
> > +        featstat[fs[2], fs[3]] = on;
> > +}
> > +
> > +END {
> > +    sets[1] = "REQUIRED";
> > +    sets[2] = "DISABLED";
> > +
> > +    for (ns in sets) {
> > +        s = sets[ns];
> > +
> > +        printf "/*\n";
> > +        printf " * %s features:\n", s;
> > +        printf " *\n";
> > +        fstr = "";
> > +        for (i = 0; i < ncapints; i++) {
> > +            mask = 0;
> > +            for (j = 0; j < 32; j++) {
> > +                nfeat = i*32 + j;
> > +                feat = feats[nfeat];
> > +                if (feat) {
> > +                    st = !!featstat[s, feat];
> > +                    if (st) {
> > +                        nfstr = fstr " " feat;
> > +                        if (length(nfstr) > 72) {
> > +                            printf " *   %s\n", fstr;
> > +                            nfstr = " " feat;
> > +                        }
> > +                        fstr = nfstr;
> > +                    }
> > +                    mask += st * (2 ^ j);
>
> nit: This expression can be changed to mask += (2 ^j) and moved inside 
> the 'if (st)' branch. Essentially only add a bit iff that status of the 
> relevant feature in the kconfig is y, which is signified by the value of 
> 'st' variable.

I will do a polish and send v4.

> > +                }
> > +            }
> > +            masks[i] = mask;
> > +        }
> > +        printf " *   %s\n */\n\n", fstr;
> > +
> > +        for (i = 0; i < ncapints; i++) {
> > +            printf "#define %s_MASK%d\t0x%08x\n", s, i, masks[i];

I should append 'U' here too.

> > +        }
> > +
> > +        printf "#define %s_MASK_CHECK BUILD_BUG_ON_ZERO(NCAPINTS != 
> > %d)\n\n", s, ncapints;
> > +    }
> > +
> > +    printf "#endif /* _ASM_X86_FEATUREMASKS_H */\n";
> > +}