Re: [PATCH 05/16] KVM: arm64: selftests: Add protected-VM boot trampoline

[Joey Gouly]

On Wed, Nov 04, 2026 at 08:48:31AM +0000, Fuad Tabba wrote:
> EL2 takes only PC and X0 from the host when it boots a protected vCPU,
> and resets everything else. So the registers the selftest library sets
> before the first run never reach the guest.
> 
> Boot a protected guest through a trampoline that restores X0-X7, seven
> EL1 system registers and the stack pointer from a block X0 points to,
> then enables the MMU and branches to the guest's entry point.
> 
> Co-developed-by: Will Deacon <will@xxxxxxxxxx>
> Signed-off-by: Will Deacon <will@xxxxxxxxxx>
> Signed-off-by: Fuad Tabba <fuad.tabba@xxxxxxxxx>

Similar idea to the 'realm-boot' I added, and mentioned previously. I
think it should work for Realms too.

Reviewed-by: Joey Gouly <joey.gouly@xxxxxxx>

> ---
>  tools/testing/selftests/kvm/Makefile.kvm      |  1 +
>  .../selftests/kvm/include/arm64/pkvm.h        | 50 ++++++++++++++++
>  .../selftests/kvm/lib/arm64/pvm-entry.S       | 58 +++++++++++++++++++
>  3 files changed, 109 insertions(+)
>  create mode 100644 tools/testing/selftests/kvm/include/arm64/pkvm.h
>  create mode 100644 tools/testing/selftests/kvm/lib/arm64/pvm-entry.S
> 
> diff --git a/tools/testing/selftests/kvm/Makefile.kvm b/tools/testing/selftests/kvm/Makefile.kvm
> index 17a4256e90819..c254e82f9a786 100644
> --- a/tools/testing/selftests/kvm/Makefile.kvm
> +++ b/tools/testing/selftests/kvm/Makefile.kvm
> @@ -35,6 +35,7 @@ LIBKVM_arm64 += lib/arm64/gic_v3.c
>  LIBKVM_arm64 += lib/arm64/gic_v3_its.c
>  LIBKVM_arm64 += lib/arm64/handlers.S
>  LIBKVM_arm64 += lib/arm64/processor.c
> +LIBKVM_arm64 += lib/arm64/pvm-entry.S
>  LIBKVM_arm64 += lib/arm64/spinlock.c
>  LIBKVM_arm64 += lib/arm64/ucall.c
>  LIBKVM_arm64 += lib/arm64/vgic.c
> diff --git a/tools/testing/selftests/kvm/include/arm64/pkvm.h b/tools/testing/selftests/kvm/include/arm64/pkvm.h
> new file mode 100644
> index 0000000000000..6ef769b8ff977
> --- /dev/null
> +++ b/tools/testing/selftests/kvm/include/arm64/pkvm.h
> @@ -0,0 +1,50 @@
> +/* SPDX-License-Identifier: GPL-2.0 */
> +/*
> + * Copyright (C) 2025 Google LLC
> + * Author: Fuad Tabba <fuad.tabba@xxxxxxxxx>
> + * Author: Will Deacon <will@xxxxxxxxxx>
> + */
> +
> +#ifndef SELFTEST_KVM_ARM64_PKVM_H
> +#define SELFTEST_KVM_ARM64_PKVM_H
> +
> +#ifndef __ASSEMBLER__
> +/*
> + * Register state the boot trampoline (pvm-entry.S) restores. Only PC and X0
> + * survive to a protected guest's first run, so X0 points at this block.
> + */
> +struct pvm_boot_args {
> +	u64	jump_tgt;
> +
> +	u64	regs[8];
> +	u64	cpacr_el1;
> +	u64	sctlr_el1;
> +	u64	tcr_el1;
> +	u64	mair_el1;
> +	u64	ttbr0_el1;
> +	u64	vbar_el1;
> +
> +	u64	tpidr_el1;
> +	u64	sp_el1;
> +};
> +#endif
> +
> +#define PVM_BOOT_ARGS_OFF_JUMP_TGT	0
> +#define PVM_BOOT_ARGS_OFF_X0		(PVM_BOOT_ARGS_OFF_JUMP_TGT + 8)
> +#define PVM_BOOT_ARGS_OFF_X1		(PVM_BOOT_ARGS_OFF_X0 + 8)
> +#define PVM_BOOT_ARGS_OFF_X2		(PVM_BOOT_ARGS_OFF_X1 + 8)
> +#define PVM_BOOT_ARGS_OFF_X3		(PVM_BOOT_ARGS_OFF_X2 + 8)
> +#define PVM_BOOT_ARGS_OFF_X4		(PVM_BOOT_ARGS_OFF_X3 + 8)
> +#define PVM_BOOT_ARGS_OFF_X5		(PVM_BOOT_ARGS_OFF_X4 + 8)
> +#define PVM_BOOT_ARGS_OFF_X6		(PVM_BOOT_ARGS_OFF_X5 + 8)
> +#define PVM_BOOT_ARGS_OFF_X7		(PVM_BOOT_ARGS_OFF_X6 + 8)
> +#define PVM_BOOT_ARGS_OFF_CPACR_EL1	(PVM_BOOT_ARGS_OFF_X7 + 8)
> +#define PVM_BOOT_ARGS_OFF_SCTLR_EL1	(PVM_BOOT_ARGS_OFF_CPACR_EL1 + 8)
> +#define PVM_BOOT_ARGS_OFF_TCR_EL1	(PVM_BOOT_ARGS_OFF_SCTLR_EL1 + 8)
> +#define PVM_BOOT_ARGS_OFF_MAIR_EL1	(PVM_BOOT_ARGS_OFF_TCR_EL1 + 8)
> +#define PVM_BOOT_ARGS_OFF_TTBR0_EL1	(PVM_BOOT_ARGS_OFF_MAIR_EL1 + 8)
> +#define PVM_BOOT_ARGS_OFF_VBAR_EL1	(PVM_BOOT_ARGS_OFF_TTBR0_EL1 + 8)
> +#define PVM_BOOT_ARGS_OFF_TPIDR_EL1	(PVM_BOOT_ARGS_OFF_VBAR_EL1 + 8)
> +#define PVM_BOOT_ARGS_OFF_SP_EL1	(PVM_BOOT_ARGS_OFF_TPIDR_EL1 + 8)
> +
> +#endif /* SELFTEST_KVM_ARM64_PKVM_H */
> diff --git a/tools/testing/selftests/kvm/lib/arm64/pvm-entry.S b/tools/testing/selftests/kvm/lib/arm64/pvm-entry.S
> new file mode 100644
> index 0000000000000..a0974cde78da6
> --- /dev/null
> +++ b/tools/testing/selftests/kvm/lib/arm64/pvm-entry.S
> @@ -0,0 +1,58 @@
> +/* SPDX-License-Identifier: GPL-2.0 */
> +/*
> + * Copyright (C) 2025 Google LLC
> + * Author: Fuad Tabba <fuad.tabba@xxxxxxxxx>
> + * Author: Will Deacon <will@xxxxxxxxxx>
> + */
> +
> +#include "pkvm.h"
> +
> +	.text
> +	.balign 16
> +	.globl	pvm_entry_start
> +pvm_entry_start:
> +	mov	x30, x0
> +
> +	ldr	x0, [x30, #PVM_BOOT_ARGS_OFF_X0]
> +	ldr	x1, [x30, #PVM_BOOT_ARGS_OFF_X1]
> +	ldr	x2, [x30, #PVM_BOOT_ARGS_OFF_X2]
> +	ldr	x3, [x30, #PVM_BOOT_ARGS_OFF_X3]
> +	ldr	x4, [x30, #PVM_BOOT_ARGS_OFF_X4]
> +	ldr	x5, [x30, #PVM_BOOT_ARGS_OFF_X5]
> +	ldr	x6, [x30, #PVM_BOOT_ARGS_OFF_X6]
> +	ldr	x7, [x30, #PVM_BOOT_ARGS_OFF_X7]
> +
> +	ldr	x8, [x30, #PVM_BOOT_ARGS_OFF_JUMP_TGT]
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_CPACR_EL1]
> +	msr	cpacr_el1, x9
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_TCR_EL1]
> +	msr	tcr_el1, x9
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_MAIR_EL1]
> +	msr	mair_el1, x9
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_TTBR0_EL1]
> +	msr	ttbr0_el1, x9
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_VBAR_EL1]
> +	msr	vbar_el1, x9
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_TPIDR_EL1]
> +	msr	tpidr_el1, x9
> +
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_SP_EL1]
> +	mov	sp, x9
> +
> +	/* No stale TLB entries, and the writes above in effect, before the MMU is on. */
> +	tlbi	vmalle1
> +	dsb	nsh
> +	isb
> +	ldr	x9, [x30, #PVM_BOOT_ARGS_OFF_SCTLR_EL1]
> +	msr	sctlr_el1, x9
> +	isb
> +
> +	br	x8
> +	.globl	pvm_entry_end
> +pvm_entry_end:
> -- 
> 2.47.3
>